To do this, you of course must have exact knowledge of everything that is allowed in your language.
Identify all the different kinds of syntax and give them all names and write out their definitions.
This is usually done using the BNF notation.
Here is what we need for our example language:


First level, lexical structure:

  <digit> ::=  "0" | "1" | "2" | "3" | "4" | "5" | "6" | "7" | "8" | "9"

  <letter> ::= "a" | "b" | "c" | "d" | "e" | "f" | "g" | "h" | "i" | "j" | "k" | "l" | "m"
             | "n" | "o" | "p" | "q" | "r" | "s" | "t" | "u" | "v" | "w" | "x" | "y" | "z"

  <number> ::= <digit> <digit> *

  <name> ::= <letter> ( <letter> | <digit> ) *


Second level, Syntactic structure, taking the lexical forms as simple items

  <value> ::= name | number | "(" <expression> ")"

  <expression> ::= <value> ( <operator> <value> ) *

  <operator> ::= "+" | "-" | "*" | "/" | "<" | ">" | "<=" | ">=" | "==" | "!=" | "^" | "%" | "and" | "or" | "not"

  <statement> ::= <output> | <loop> | <conditional> | <assignment> | <block>

  <output> ::= "print" <expression>

  <assignment> ::= name "=" <expression>

  <loop> ::= "while" <expression> "do" <statement>

  <conditional> ::= "if" <expression> "then" <statement> { "else" <statement> } "fi"

  <block> ::= "{" { <sequence> } "}"

  <sequence> ::= <statement> ( ";" <statement> ) *